The command computes the
i-th cohomology group of
F as a vector space over the coefficient field of
X. For i>0 this is currently done via local duality, while for i=0 it is computed as a limmit of Homs. Eventually there will exist an alternative option for computing sheaf cohomology via the Bernstein-Gelfand-Gelfand correspondence
As examples we compute the Picard numbers, Hodge numbers and dimension of the infinitesimal deformation spaces of various quintic hypersurfaces in projective fourspace (or their Calabi-Yau small resolutions)
We will make computations for quintics V in the family given by
x05+x15+x25+x35+x45-5λx0x1x2x3x4=0
for various values of
λ. If
λ is general (that is,
λ not a 5-th root of unity, 0 or
∞), then the quintic
V is smooth, so is a Calabi-Yau threefold, and in that case the Hodge numbers are as follows.
h1,1(V)=1, h2,1(V) = h1,2(V) = 101,
so the Picard group of V has rank 1 (generated by the hyperplane section) and the moduli space of V (which is unobstructed) has dimension 101:
Quintic = Proj(QQ[x_0..x_4]/ideal(x_0^5+x_1^5+x_2^5+x_3^5+x_4^5-101*x_0*x_1*x_2*x_3*x_4)) |
singularLocus(Quintic) |
omegaQuintic = cotangentSheaf(Quintic); |
h11 = rank HH^1(omegaQuintic) |
h12 = rank HH^2(omegaQuintic) |
By Hodge duality this is
h2,1. Directly
h2,1 could be computed as
h21 = rank HH^1(cotangentSheaf(2,Quintic)) |
The Hodge numbers of a (smooth) projective variety can also be computed directly using the
hh command:
hh^(2,1)(Quintic) |
hh^(1,1)(Quintic) |
Using the Hodge number we compute the topological Euler characteristic of V:
When
λ is a 5th root of unity the quintic V is singular. It has 125 ordinary double points (nodes), namely the orbit of the point
(1:λ:λ:λ:λ) under a natural action of
ℤ/53. Then
V has a projective small resolution
W which is a Calabi-Yau threefold (since the action of
ℤ/53 is transitive on the sets of nodes of
V, or for instance, just by blowing up one of the
(1,5) polarized abelian surfaces
V contains). Perhaps the most interesting such 3-fold is the one for the value
λ=1, which is defined over
ℚ and is modular (see Schoen’s work). To compute the Hodge numbers of the small resolution
W of
V we proceed as follows:
SchoensQuintic = Proj(QQ[x_0..x_4]/ideal(x_0^5+x_1^5+x_2^5+x_3^5+x_4^5-5*x_0*x_1*x_2*x_3*x_4)) |
Z = singularLocus(SchoensQuintic) |
degree Z |
II'Z = sheaf module ideal Z |
The defect of W (that is,
h1,1(W)-1) can be computed from the cohomology of the ideal sheaf of the singular locus Z of V twisted by 5 (see Werner’s thesis):
defect = rank HH^1(II'Z(5)) |
h11 = defect + 1 |
The number
h2,1(W) (the dimension of the moduli space of W) can be computed (Clemens-Griffiths, Werner) as
dim H0(IZ(5))/JacobianIdeal(V)5.
quinticsJac = numgens source basis(5,ideal Z) |
h21 = rank HH^0(II'Z(5)) - quinticsJac |
In other words W is rigid. It has the following topological Euler characteristic.
chiW = euler(Quintic)+2*degree(Z) |